; Author: Juergen Lorenz
; ju (at) jugilo (dot) de
;
; Copyright (c) 2013, Juergen Lorenz
; All rights reserved.
; 
; Redistribution and use in source and binary forms, with or without
; modification, are permitted provided that the following conditions are
; met:
; 
; Redistributions of source code must retain the above copyright
; notice, this list of conditions and the following disclaimer.
; 
; Redistributions in binary form must reproduce the above copyright
; notice, this list of conditions and the following disclaimer in the
; documentation and/or other materials provided with the distribution.
; 
; Neither the name of the author nor the names of its contributors may be
; used to endorse or promote products derived from this software without
; specific prior written permission. 
; 
; THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS "AS
; IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED
; TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A
; PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT
; HOLDERS OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL,
; SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED
; TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR
; PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF
; LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING
; NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF THIS
; SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
; 
; Last update: Jul 25, 2013
;
;;; simplifying Marc Feeley's continuation interface with some additions,
;;; i.a. by  Matt Might

(module continuations
  (continuations catch capture graft throw continuation? continuation
                 goto continuation->procedure)

  (import scheme
          (rename (only chicken
                        continuation-capture
                        continuation-graft
                        continuation-return
                        continuation?)
                  (continuation-capture capture)
                  (continuation-graft graft)
                  (continuation-return throw)))

(define-syntax catch
  (syntax-rules ()
    ((_ cont xpr . xprs)
     (capture (lambda (cont) xpr . xprs)))))

(define (continuation->procedure cont)
  (lambda vals (apply throw cont vals)))

(define (continuation)
  (capture (lambda (cc) (throw cc cc))))

(define (goto cc) (throw cc cc))

(define (continuations . args)
  (let ((lst '(catch capture continuation continuation?
                continuation->procedure goto graft throw)))
    (if (null? args)
      lst
      (case (car args)
        ((catch)
         '(macro ()
             ((_ cont xpr . xprs)
              #t
              (capture (lambda (cont) xpr . xprs)))))
        ((capture)
         '(procedure (result)
            ((_ proc)
             (procedure? proc)
             "alias for continuation-capture")))
        ((continuation?)
         '(procedure (result)
            ((_ xpr) #t (boolean? result))))
        ((continuation->procedure)
         '(procedure (result)
            ((_ cont)
             (continuation? cont)
             (procedure? result))))
        ((graft)
         '(procedure (return)
            ((_ cont thunk)
             (and (continuation? cont) (procedure? thunk))
             "alias for continuation-graft")))
        ((throw)
         '(procedure (result)
            ((_ cont . vals)
             (continuation? cont)
             "alias for continuation-return")))
        ((continuation)
         '(procedure (result)
            ((_)
             #t
             (continuation? result))))
        ((goto cont)
         '(procedure (result)
            (continuation? cont)
            (continuation? result)))
        (else lst)))))

) ; end continuations

(module continuations-used
  (continuations-used make-amb make-threads iterate)
(import scheme continuations
        (only chicken when unless error)
        (only extras format))

;;; iterators
(define-syntax iterate
  (syntax-rules ()
    ((_ var iterator xpr . xprs)
     (let ((it iterator) (it-cont #f))
       (let loop ()
         (let ((cc (continuation)))
           (if (continuation? cc)
             ;; first let-pass
             (if (continuation? it-cont)
               (throw it-cont (void))
               (it (lambda (val)
                   (catch next-cc
                     (throw cc (cons next-cc val))))))
             ;; second let-pass (cc is now pair)
             (let ((next-cont (car cc))
                   (next-val (cdr cc)))
               (set! it-cont next-cont)
               (let ((var next-val)) xpr . xprs)
               (loop)))))))))

;; amb packaged as a message-passing object
;; ----------------------------------------
(define (make-amb)
  (let ((stack '()))
    (define (amb-fail)
      (if (null? stack)
        (error 'amb-fail "amb-stack exhausted")
        (begin
          (let ((choice (car stack)))
            (set! stack (cdr stack))
            (goto choice)))))
    (define (amb-choose . choices)
      (let ((cc (continuation)))
        (cond
          ((null? choices)
           (amb-fail))
          ((pair? choices)
           (let ((choice (car choices)))
             (set! choices (cdr choices))
             (set! stack (cons cc stack))
             choice)))))
    (define (amb-assert xpr)
      (if xpr
        #t
        (amb-fail)))
    (lambda (sym)
      (case sym
        ((fail) amb-fail)
        ((choose) amb-choose)
        ((assert) amb-assert)
        (else
          (error 'make-amb
                 (format #f "message not in ~s: ~s"
                         '(fail choose assert)
                         sym)))))))

;; cooperative threads packaged as a message-passing object
;; -------------------------------------------------------
(define (make-threads)
  ;; a queue implemented by two lists giving
  ;; amortized constant time access to its items
  (let ((in '()) (out '()))
    (define (enq! var)
      (set! in (cons var in)))
    (define (deq!)
      (when (null? out)
        (set! out (reverse in))
        (set! in '()))
      (let ((var (car out)))
        (set! out (cdr out))
        var))
    (define threads-halt #f)
    (define (threads-spawn thunk)
      (let ((cc (continuation)))
        (if (continuation? cc)
          (enq! cc)
          (begin (thunk) (threads-quit)))))
    (define (threads-yield)
      (let ((cc (continuation)))
        (if (and (continuation? cc)
                 (not (and (null? in) (null? out))))
          (let ((next-thread (deq!)))
            (enq! cc)
            (throw next-thread 'resume)))))
    (define (threads-quit)
      (if (and (null? in) (null? out))
        (threads-halt)
        (throw (deq!) 'resume)))
    (define (threads-start)
      (let ((cc (continuation)))
        (when cc;(continuation? cc)
          (set! threads-halt (lambda () (throw cc #f)))
          (unless (and (null? in) (null? out))
            (throw (deq!) 'resume)))))
    (lambda (sym)
      (case sym
        ((halt) threads-halt)
        ((spawn) threads-spawn)
        ((yield) threads-yield)
        ((quit) threads-quit)
        ((start) threads-start)
        (else
          (error 'make-threads
                 (format #f "message not in ~s: ~s"
                         '(spawn yield quit start halt)
                         sym)))))))

(define (continuations-used . args)
  (let ((lst '(iterate make-amb make-threads)))
    (if (null? args)
      lst
      (case (car args)
        ((iterate)
         '(macro ()
             ((_ var iterator xpr . xprs)
              (and (procedure? iterator)
                   "(iterator container) -> (lambda (yield) ...)")
              "applies yield to every var in contqainer")))
        ((make-amb)
         '(procedure (result)
            ((_)
             #t
             (and "ambiguous choice"
                  (procedure? result)
                  "result accepts symbols choose fail and assert"))))
        ((make-threads)
         '(procedure (result)
            ((_)
             #t
             (and "cooperative threads"
                  (procedure? result)
                  "result accepts symbols halt, spawn, yield, quit and start"))))
        (else lst)))))

) ; module continuations-used