; Author: Juergen Lorenz
; ju (at) jugilo (dot) de
;
; Copyright (c) 2013-2016, Juergen Lorenz
; All rights reserved.
; 
; Redistribution and use in source and binary forms, with or without
; modification, are permitted provided that the following conditions are
; met:
; 
; Redistributions of source code must retain the above copyright
; notice, this list of conditions and the following disclaimer.
; 
; Redistributions in binary form must reproduce the above copyright
; notice, this list of conditions and the following disclaimer in the
; documentation and/or other materials provided with the distribution.
; 
; Neither the name of the author nor the names of its contributors may be
; used to endorse or promote products derived from this software without
; specific prior written permission. 
; 
; THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS "AS
; IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED
; TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A
; PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT
; HOLDERS OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL,
; SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED
; TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR
; PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF
; LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING
; NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF THIS
; SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
; 
; Last update: Oct 16, 2016
;
;;; simplifying Marc Feeley's continuation interface with some additions,
;;; i.a. by  Matt Might

(require-extension lolevel)

(module continuations
  (continuations catch capture graft throw continuation? continuation
                 current call goto continuation->procedure
                 escape-procedure escape-procedure?)

  (import scheme
          (rename (only chicken
                        continuation-capture
                        continuation-graft
                        continuation-return
                        continuation?
                        define-values
                        case-lambda
                        print
                        gensym)
                  (continuation-capture capture)
                  (continuation-graft graft)
                  (continuation-return throw))
          (only lolevel extend-procedure procedure-data
                extended-procedure?))

(define-syntax catch
  (syntax-rules ()
    ((_ cont xpr . xprs)
     (capture (lambda (cont) xpr . xprs)))))

(define (continuation->procedure cont)
  (lambda vals (apply throw cont vals)))

(define (call receiver)
  (capture (lambda (cc)
             (receiver (continuation->procedure cc)))))

(define (current)
  (capture (lambda (cc) (throw cc cc))))

(define (continuation) ; deprecated
  (capture (lambda (cc) (throw cc cc))))

(define (goto cc) (throw cc cc))

;;; Matt Wright's functional interface
(define-values (escape-procedure escape-procedure?)
  (let ((type (gensym 'escape-procedure)))
    (values
      (lambda ()
        (call-with-current-continuation
          (lambda (cc)
                   (cc (extend-procedure cc type)))))
      (lambda (xpr)
        (and (extended-procedure? xpr)
             (eq? (procedure-data xpr) type)))
      )))

(define continuations
  (let ((alist '(
          (escape-procedure
            procedure:
            (escape-procedure)
            "captures the current continuation as an escape procedure")
          (escape-procedure?
            procedure:
            (escape-procedure? xpr)
            "checks if xpr is an escape procedure")
          (catch
            macro:
            (catch cc xpr ....)
            "catches cc as a continuation"
            "and evaluates xpr .... in this context")
          (capture
            procedure:
            (capture receiver)
             "alias for continuation-capture")
          (continuation?
            procedure:
            (continuation xpr)
            "tests if xpr is a continuation")
          (continuation->procedure
            procedure:
            (continuation->procedure cc)
            "transforms a continuation into a procedure")
          (call
            procedure:
            (call receiver)
            "the same as call/cc, but implemented via capture")
          (graft
            procedure:
            (graft cc thunk)
            "alias for continuation-graft")
          (throw
            procedure:
            (throw cc val ...)
            "alias for continuation-return")
          (current
            procedure:
            (current)
            "captures the current continuation as a continuation")
          (goto
            procedure:
            (goto cc)
            "jumps to the continuation cc")
          (continuations
            procedure:
            (continuations sym ..)
            "documentation procedure")
          )))
    (case-lambda
      (() (map car alist))
      ((sym)
       (let ((result (assq sym alist)))
         (if result
           (for-each print result)
           (begin
             (print "choose one of "
                    (map car alist)))))))))

) ; end continuations

(module continuations-used
  (continuations-used make-amb make-threads iterate)
(import scheme continuations
        (only chicken when unless error print case-lambda)
        (only extras format))

;;; iterators
(define-syntax iterate
  (syntax-rules ()
    ((_ var iterator xpr . xprs)
     (let ((it iterator) (it-cont #f))
       (let loop ()
         (let ((cc (continuation)))
           (if (continuation? cc)
             ;; first let-pass
             (if (continuation? it-cont)
               (throw it-cont (void))
               (it (lambda (val)
                   (catch next-cc
                     (throw cc (cons next-cc val))))))
             ;; second let-pass (cc is now pair)
             (let ((next-cont (car cc))
                   (next-val (cdr cc)))
               (set! it-cont next-cont)
               (let ((var next-val)) xpr . xprs)
               (loop)))))))))

;; amb packaged as a message-passing object
;; ----------------------------------------
(define (make-amb)
  (let ((stack '()))
    (define (amb-fail)
      (if (null? stack)
        (error 'amb-fail "amb-stack exhausted")
        (begin
          (let ((choice (car stack)))
            (set! stack (cdr stack))
            (goto choice)))))
    (define (amb-choose . choices)
      (let ((cc (continuation)))
        (cond
          ((null? choices)
           (amb-fail))
          ((pair? choices)
           (let ((choice (car choices)))
             (set! choices (cdr choices))
             (set! stack (cons cc stack))
             choice)))))
    (define (amb-assert xpr)
      (if xpr
        #t
        (amb-fail)))
    (lambda (sym)
      (case sym
        ((fail) amb-fail)
        ((choose) amb-choose)
        ((assert) amb-assert)
        (else
          (error 'make-amb
                 (format #f "message not in ~s: ~s"
                         '(fail choose assert)
                         sym)))))))

;; cooperative threads packaged as a message-passing object
;; -------------------------------------------------------
(define (make-threads)
  ;; a queue implemented by two lists giving
  ;; amortized constant time access to its items
  (let ((in '()) (out '()))
    (define (enq! var)
      (set! in (cons var in)))
    (define (deq!)
      (when (null? out)
        (set! out (reverse in))
        (set! in '()))
      (let ((var (car out)))
        (set! out (cdr out))
        var))
    (define threads-halt #f)
    (define (threads-spawn thunk)
      (let ((cc (continuation)))
        (if (continuation? cc)
          (enq! cc)
          (begin (thunk) (threads-quit)))))
    (define (threads-yield)
      (let ((cc (continuation)))
        (if (and (continuation? cc)
                 (not (and (null? in) (null? out))))
          (let ((next-thread (deq!)))
            (enq! cc)
            (throw next-thread 'resume)))))
    (define (threads-quit)
      (if (and (null? in) (null? out))
        (threads-halt)
        (throw (deq!) 'resume)))
    (define (threads-start)
      (let ((cc (continuation)))
        (when cc;(continuation? cc)
          (set! threads-halt (lambda () (throw cc #f)))
          (unless (and (null? in) (null? out))
            (throw (deq!) 'resume)))))
    (lambda (sym)
      (case sym
        ((halt) threads-halt)
        ((spawn) threads-spawn)
        ((yield) threads-yield)
        ((quit) threads-quit)
        ((start) threads-start)
        (else
          (error 'make-threads
                 (format #f "message not in ~s: ~s"
                         '(spawn yield quit start halt)
                         sym)))))))

(define continuations-used
  (let ((alist '(
          (iterate
            macro:
            (iterate var iterator xpr ....)
            "iterator should accept a container argument"
            "and return a generator, i.e. a function"
            "which can yield any item of the container."
            "interate inspects them in turn")
          (make-amb
            procedure:
            (make-amb)
            "ambiguous choice"
            "result accepts symbols choose fail and assert")
          (make-threads
            procedure:
            (make-threads)
            "cooperative threads"
            "result accepts symbols halt, spawn, yield, quit and start")
          (continuations-used
            procedure:
            (continuations sym ..)
            "documentation procedure")
          )))
    (case-lambda
      (() (map car alist))
      ((sym)
       (let ((result (assq sym alist)))
         (if result
           (for-each print result)
           (begin
             (print "choose one of "
                    (map car alist)))))))))

) ; module continuations-used