#|[
Author: Juergen Lorenz
ju (at) jugilo (dot) de

Copyright (c) 2015, Juergen Lorenz
All rights reserved.

Redistribution and use in source and binary forms, with or without
modification, are permitted provided that the following conditions are
met:

Redistributions of source code must retain the above copyright
notice, this list of conditions and the following disclaimer.

Redistributions in binary form must reproduce the above copyright
notice, this list of conditions and the following disclaimer in the
documentation and/or other materials provided with the distribution.

Neither the name of the author nor the names of its contributors may be
used to endorse or promote products derived from this software without
specific prior written permission. 

THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS "AS
IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED
TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A
PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT
HOLDERS OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL,
SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED
TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR
PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF
LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING
NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF THIS
SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
]|#

; This is a variant of the datatype egg, written by Felix Winkelmann,
; which in turn is patterned after the datatype facility described in
; the classic "Essentials of programming languages" (EOPL) by Friedman,
; Wand and Haynes. It simplyfies Felix' code by using the facilities of
; my bindings egg, changes the names and syntax a little and adds
; abstract as well as object types. Concrete types are variant records
; as EOPL's datatypes, but constructor arguments can accept zero or more
; predicates, abstract types hide the constructors of its implementing
; concrete types like the corresponding language construct of ML, and
; object types are message-handlers, where the messages are defined as
; concrete-types. 

(require-library bindings)

(module datatypes (define-concrete-type
                  (concrete-case invoke)
                  define-abstract-type
                  define-object-type
                  make-base-object
                  object?
                  Types
                  Info
                  Invariant
                  Ancestors
                  datatypes)

  (import scheme chicken bindings
          (only data-structures conjoin disjoin o))
  (import-for-syntax (only bindings macro-rules bindable? bind-case))

(define-macro (define-concrete-type TYPE type? . variants)
  (where ((list-of? list?) variants)
         (not (null? variants))
         ((list-of? symbol?) (map car variants))
         ((list-of? list?) (map cdr variants)))
  `(begin
     (define (,type? form) (##sys#structure? form ',TYPE))
     ,@(map (lambda (variant)
              (bind-case variant
                ((variantname . checkedargs)
                 (let ((variantargs (map car checkedargs))
                       (variantpreds (map cdr checkedargs)))
                   `(define (,variantname ,@variantargs)
                      (##sys#make-structure
                       ',TYPE ',variantname
                       ,@(map (lambda (name pred)
                                `(if (##core#check (,pred ,name))
                                   ,name
                                   (##sys#signal-hook
                                    #:type-error 
                                    "bad argument type to variant constructor"
                                    ,name ',variantname ',name)))
                              variantargs (map (lambda (preds)
                                                 `(conjoin ,@preds))
                                               variantpreds))))))))
            variants)))

(define-macro concrete-case
  (macro-rules (else)
    ((_ (xpr type?) . clauses)
     (where ((conjoin (list-of? list?)
                      (disjoin (bindable? ((Constr . args) . xprs))
                               (bindable? (else . xprs))))
             clauses)
            (not (null? clauses)))
     `(let ((tmp ,xpr))
        (if (##core#check (,type? tmp))
          (let ((tag (##sys#slot tmp 1)))
            (cond ,@(map (lambda (clause)
                           (bind-case clause
                             (((variantname . variantargs) xpr . xprs)
                              `((eq? tag ',variantname)
                                (invoke
                                  ',variantname tmp 
                                  ,(length variantargs) 
                                  (lambda ,variantargs
                                    ,xpr ,@xprs))))
                             ((else xpr . xprs)
                              `(else (let () ,xpr ,@xprs)))
                             ))
                         clauses)))
          (##sys#signal-hook #:type-error
             "typecheck didn't pass in concrete-case"
             `(,',type?  ,tmp)))))))

(define (invoke name block count proc)
  (apply 
   proc
   (let ((limit (fx- (##sys#size block) 2)))
     (let rec ((i 0))
       (cond
         ((fx>= i count) '())
         ((fx>= i limit) (error 'concrete-case
                                "too many record fields accessed"
                                name block))
         (else (cons (##sys#slot block (fx+ i 2))
                     (rec (fx+ i 1)))))))))

(define-macro define-abstract-type
  (macro-rules (with printer reader)
    ((_ TYPE type?
        (variant . variants)
        (with routine . routines)
        (printer . printers)
        (reader . readers))
     (where ((conjoin (list-of? list?) (o not null?)) variants))
     (let ((variants (cons variant variants))
           (routines (cons routine routines)))
       (let ((names (map caar routines))
             (args (map cdar routines))
             (bodies (map cdr routines)))
         `(define-values (,type?  ,@names)
            (letrec ,(map (lambda (n) `(,n #f)) names)
              (define-concrete-type ,TYPE ,type?
                                    ,variants)
              ,@(map (lambda (n a b) `(set! ,n (lambda ,a ,@b)))
                     names args bodies)
              ,(if (null? printers)
                 #f
                 `(define-record-printer ,TYPE ,(car printers)))
              ,(if (null? readers)
                 #f
                 `(define-reader-ctor ',TYPE ,(car readers)))
              (values ,type? ,@names))))))
    ((_ TYPE type?
        (variant . variants)
        (with . routines)
        (printer . printers))
     `(define-abstract-type ,TYPE ,type?
        (,variant ,@variants)
        (with ,@routines)
        (printer ,@printers)
        (reader)))
    ((_ TYPE type?
        (variant . variants)
        (with . routines))
     `(define-abstract-type ,TYPE ,type?
        (,variant ,@variants)
        (with ,@routines)
        (printer)
        (reader)))))

;;; (define-object-type CHILD child? make-child
;;;   ((parent parent?) (x x? ...) ...)      ; state variables
;;;   (override  ((A a ...) apr . aprs) ...) ; overridden messages
;;;   ((X (x x? ...) ...) xpr . xprs)        ; new messages
;;;   ....)
;;; -------------------------------------------------
(define-macro define-object-type
  (macro-rules Types Invariant Info Ancestors (override)
    ((_ CHILD child? make-child
        ((parent parent?) . xss)
        (override . obody)
        . body)
     (where ((list-of? list?) xss)
            ((list-of? (bindable? ((A . as) apr . aprs)))
             obody)
            (not (null? body))
            ((list-of? (bindable? ((X . xs) xpr . xprs)))
             body)
            )
     (let ((xs (map car xss))
           (xs? (map (lambda (ps) `(conjoin ,@ps)) (map cdr xss)))
           (messages (map car body))
           (omessages (map car obody))
           (extract-args (lambda (as)
                           (if ((list-of? symbol?) as)
                             as
                             (map car as)))))
       ;(xpr:val xs xs? messages)
       (let ((message-names (append (map car omessages)
                                    (map car messages)))
             (arg-names
               (append (map extract-args (map cdr omessages))
                       (map extract-args (map cdr messages)))))
         ;(xpr:val message-names arg-names)
         `(define-values (,make-child ,child? ,@message-names)
            (let ((type (gensym ',CHILD)))
              ;; note, that the MSG type is distributed over the whole
              ;; object hierarchy, since the parents, including object,
              ;; all implement this type locally with the same name.
              ;; This is the reason, that the else clause in
              ;; concrete-case branches to the parent.
              (define-concrete-type MSG msg?
                ;;; only new messages
                ,@messages)
              (values
                ;; constructor
                (lambda (,parent ,@xs)
                  (let ((,parent ,parent) ,@(map (lambda (x) `(,x ,x)) xs))
                    (lambda (msg)
                      (concrete-case (msg msg?)
                        ;; automatic overrides
                        ((,Types)
                         (cons type (,parent (,Types))))
                        ((,Invariant)
                         (if (and (,parent (,Invariant))
                                  ,@(map (lambda (n p)
                                           `(,p ,n))
                                         xs xs?))
                           '(and (,parent (,Invariant))
                                 ,@xss)
                           #f))
                        ((,Info)
                         (append (,parent (,Info))
                                 ',messages))
                        ((,Ancestors)
                         (cons ,parent (,parent (,Ancestors))))
                        ;; overriden and new messages
                        ,@(map (lambda (n as bs) `((,n ,@as) ,@bs))
                               message-names
                               arg-names
                               (map cdr (append obody body)))
                        (else (,parent msg))))))
                ;; predicate
                (lambda (xpr)
                  (and (procedure? xpr)
                       (condition-case (if (memq type (xpr (,Types)))
                                         #t
                                         #f)
                         ((exn) #f))))
                ;; messages
                ,@message-names))))))))

;;; base object
(define-values (make-base-object object? Types Info Invariant Ancestors) 
  (let ((type (gensym 'OBJECT)))
    (define-concrete-type MSG msg?
      (Types)
      (Info)
      (Invariant)
      (Ancestors))
    (values
      ;; constructor
      (lambda ()
        (lambda (msg)
          (concrete-case (msg msg?)
            ((Types) (list type))
            ((Info) '((Types) (Info) (Invariant) (Ancestors)))
            ((Invariant) '())
            ((Ancestors) '()))))
      ;; predicate
      (lambda (xpr)
        (and (procedure? xpr)
             (condition-case (if (memq type (xpr (Types))) #t #f)
               ((exn) #f))))
      ;; messages
      Types
      Info
      Invariant
      Ancestors)))

;; documentation procedure
(define datatypes
  (let (
    (signatures '(
      (define-concrete-type TYPE type?
        (Constructor (arg arg? ...) ...)
        ....)
      (concrete-case (obj type?)
        ((Constructor arg ...) xpr . xprs)
        ....
        (else xpr . xprs) ..)
      (define-abstract-type TYPE type?
        (Constructor (arg arg? ...) ...)
        ....
        (with
          ((proc . args) xpr . xprs)
          ....)
        (printer (lambda (obj out) xpr . xprs))
        ..
        (reader proc)
        ..)
      (define-object-type CHILD child? make-child
        ((parent parent?) (x x? ...) ...)      ; state variables
        (override  ((A a ...) apr . aprs) ...) ; overridden messages
        ((X (x x? ...) ...) xpr . xprs)        ; new messages
        ....)
      (make-base-object)
      (object? xpr)
      (Types)
      (Info)
      (Invariant)
      (Ancestors)
      ))
    )
    (case-lambda
      (() (map car signatures))
      ((sym) (assq sym signatures)))))

) ; module datatypes