#|[
Author: Juergen Lorenz
ju (at) jugilo (dot) de

Copyright (c) 2015-2016, Juergen Lorenz
All rights reserved.

Redistribution and use in source and binary forms, with or without
modification, are permitted provided that the following conditions are
met:

Redistributions of source code must retain the above copyright
notice, this list of conditions and the following disclaimer.

Redistributions in binary form must reproduce the above copyright
notice, this list of conditions and the following disclaimer in the
documentation and/or other materials provided with the distribution.

Neither the name of the author nor the names of its contributors may be
used to endorse or promote products derived from this software without
specific prior written permission. 

THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS "AS
IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED
TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A
PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT
HOLDERS OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL,
SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED
TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR
PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF
LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING
NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF THIS
SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
]|#

;;; This module exports only one macro, local, which is inspired by the
;;; equally named operator in ML. It exports a list of definitions,
;;; depending on another hidden list of definitions. So it can be used
;;; to implement procedures depending on a common state, something what
;;; define-values can do as well.

(module locals *
  (import scheme)
  (import (only chicken print))
  (import-for-syntax
    (only chicken assert)
    (only data-structures disjoin list-of?))

;;; (local (def ...)
;;;   (var val)|
;;;   ((var . args) . body)
;;;   ....)
;;; --------------------------------------------------
;;; translates into
;;; (define-values (var ....)
;;; (begin def ...
;;;   (values val|(lambda args . body) ...)
(define-syntax local
  (er-macro-transformer
    (lambda (form rename compare?)
      (let ((defs (cadr form))
            (clauses (cddr form))
            (%begin (rename 'begin))
            (%lambda (rename 'lambda))
            (%values (rename 'values))
            (%define-values (rename 'define-values)))
        (assert ((list-of? pair?) clauses))
        (let ((vars (map (lambda (clause)
                           (cond
                             ((and (symbol? (car clause))
                                   (null? (cddr clause)))
                              (car clause))
                             ((and (pair? (car clause))
                                   (symbol? (caar clause)))
                              (caar clause))
                             (else (error "not a proper clause"))))
                         clauses))
              (vals (map (lambda (clause)
                           (if (symbol? (car clause))
                             (cadr clause)
                             `(,%lambda ,(cdar clause) 
                                ,@(cdr clause))))
                         clauses)))
          `(,%define-values ,vars
             (,%begin ,@defs
               (,%values ,@vals))))))))

(define (locals)
  (for-each print
    (list "local"
          "macro:"
          "  (local (def ...)"
          "    (var val)|((var . args) . body)"
          "    ....)"
          "exports some definitions var ...."
          "depending on other definitions def ..."
          "which are hidden")))

  ) ; module locals