#|[
Author: Juergen Lorenz
ju (at) jugilo (dot) de

Copyright (c) 2013-2014, Juergen Lorenz
All rights reserved.

Redistribution and use in source and binary forms, with or without
modification, are permitted provided that the following conditions are
met:

Redistributions of source code must retain the above copyright
notice, this list of conditions and the following disclaimer.

Redistributions in binary form must reproduce the above copyright
notice, this list of conditions and the following disclaimer in the
documentation and/or other materials provided with the distribution.

Neither the name of the author nor the names of its contributors may be
used to endorse or promote products derived from this software without
specific prior written permission. 

THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS "AS
IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED
TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A
PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT
HOLDERS OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL,
SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED
TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR
PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF
LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING
NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF THIS
SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
]|#


#|[
First a helper module with procedures, which might be useful not only in
the low-level-macros module below. The most important ones are the
destructuring procedures which do most of the dirty work. They follow
Paul Graham's definition of dbind in his classic "On Lisp" (cf. p. 232)
very closely. In Chicken, dbind for lists could look like this

  (define-syntax dbind
    (ir-macro-transformer
      (lambda (form inject compare?)
        (letrec (
          (mappend
            (lambda (fn lists)
              (apply append (map fn lists))))
          (destruc
            (lambda (pat seq)
              (let loop ((pat pat) (seq seq) (n 0))
                (if (pair? pat)
                  (let ((p (car pat)) (recu (loop (cdr pat) seq (+ n 1))))
                    (if (symbol? p)
                      (cons `(,p (list-ref ,seq ,n)) recu)
                      (let ((g (gensym)))
                        (cons (cons `(,g (list-ref ,seq ,n))
                                    (loop p g 0))
                              recu))))
                  (let ((tail `(list-tail ,seq ,n)))
                    (if (null? pat)
                      '()
                      `((,pat ,tail))))))))
          (dbind-ex
            (lambda (binds body)
              (if (null? binds)
                `(begin ,@body)
                `(let ,(map (lambda (b) (if (pair? (car b)) (car b) b))
                            binds)
                   ,(dbind-ex
                      (mappend (lambda (b) (if (pair? (car b)) (cdr b) '()))
                               binds)
                      body)))))
          )         
          (let ((pat (cadr form))
                (seq (caddr form))
                (body (cdddr form))
                (gseq 'seq))
            `(let ((,gseq ,seq))
               ,(dbind-ex (destruc pat gseq) body)))))))

Note, that the destructuring procedures are local to this macro. This is
necessary in Chicken for the macro to work, in particular in compiled
code. We circumvent this problem by packaging the helpers in an extra
module, which can be imported for-symtax.
Note further, that ir-macro-transformer does all the necessary renaming
transparently behind the scene, even if the helpers are defined in
another module. In particular, gseq needn't be a gensym.
And note, that Graham's code didn't check for seq's length, i.e. 
(dbind (a b) '(1 2 3) (list a b) would happily return '(1 2).
This problem is tackled with dbind-len below.
And last, but not least, some macros should accept non-symbol literals,
in particular list-bind-case and macro-rules; dbind-lit will help here.

We'll provide two versions of destruc, one for lists - or, to be more
precise, for nested pseudolists - and one for generic sequences, used in
the bindings module.
]|#

(module macro-helpers
  (export macro-helpers bind-exception symbol-dispatcher
          dbind-ex dbind-lit dbind-len dbind-def
          list-destruc seq-destruc
          filter flatten memp assp mappend map* flatten-map*
          plist? pnull? plength plist-ref plist-tail
          vector-tail list-of? atom?
          prefixed-with? strip-prefix strip-suffix add-prefix
          extract adjoin remove-duplicates replace* 
          seq-length seq-ref seq-tail seq-length-ref-tail!)
  (import scheme (only chicken receive case-lambda 
                       define-values error
                       signal gensym print
                       make-property-condition
                       make-composite-condition))

(define (symbol-dispatcher alist)
  (case-lambda
    (()
     (map car alist))
    ((sym)
     (let ((pair (assq sym alist)))
       (if pair
         (for-each print (cdr pair))
         (print "Choose one of\n" (map car alist)))))))

(define macro-helpers
  (symbol-dispatcher '(
    (symbol-dispatcher
      (procedure: (alist) -> (procedure) or (procedure sym)))
    (bind-exception
      (procedure: (location message . arguments) -> condition))
    (list-destruc
      (procedure: (pat seq) or (pat seq glen gref gtail)
                  -> (symbols literals length-checks)))
    (seq-destruc
      (procedure: (pat seq) or (pat seq glen gref gtail)
                  -> (symbols literals length-checks)))
    (dbind-ex
      (procedure: (symbols body) -> nested-let-code))
    (dbind-lit
      (procedure: (literals) -> literals-check-code))
    (dbind-len
      (procedure: (length-checks) -> length-check-code))
    (dbind-def
      (procedure: (op binds) -> define-code))
    (map*
      (procedure: (fn . trees) -> new-tree))
    (flatten-map*
      (procedure: (fn . trees) -> new-list))
    (filter
      (procedure: (ok? lst) -> (ok not-ok)))
    (flatten
      (procedure: (tree) -> lst))
    (memp
      (procedure: (ok? lst) -> sublst or #f))
    (assp
      (procedure: (ok? alst) -> pair or #f))
    (mappend
      (procedure: (fn lists) -> lst))
    (plength
      (procedure: (pl) -> pseudolength))
    (plist?
      (procedure: (xpr) -> boolean))
    (pnull?
      (procedure: (xpr) -> boolean))
    (plist-ref
      (procedure: (pl k) -> pseudo-kth-item))
    (plist-tail
      (procedure: (pl k) -> pseudo-kth-rest))
    (seq-length
      (procedure: (seq) -> generic-length))
    (seq-ref
      (procedure: (seq k) -> generic-kth-item))
    (seq-tail
      (procedure: (seq k) -> generic-kth-rest))
    (seq-length-ref-tail!
      (procedure: (type? type-length type-ref type-tail)
                  updates (seq-length seq-ref seq-tail)))
    (add-prefix
      (procedure: (prefix id) -> new-id))
    (prefixed-with?
      (procedure: (prefix) -> (procedure id)))
    (strip-prefix
      (procedure: (prefix id) -> new-id))
    (strip-suffix
      (procedure: (suffix id) -> new-id))
    (extract
      (procedure: (ok? tree) -> lst))
    (adjoin
      (procedure: (obj lst) -> new-lst))
    (remove-duplicates
      (procedure: (lst) -> new-lst))
    (replace*
      (procedure: (what? by-fn tree) -> new-tree))
    (vector-tail
      (procedure: (vec k) -> subvector))
    (list-of?
      (procedure: (ok?) -> predicate))
    (atom?
      (procedure: (xpr) -> boolean))
    )))

(define (bind-exception loc msg . args)
  (make-composite-condition
    (make-property-condition 'exn
      'location `(,loc)
      'message msg
      'arguments (apply list args))
    (make-property-condition 'bind
      'location `(,loc)
      'message msg
      'arguments (apply list args))))


;;;; pseudolists

(define (plist? xpr) #t)
  ;(or (atom? xpr)
  ;    (and (pair? xpr) (plist? (cdr xpr))))

(define (pnull? xpr)
  (or (null? xpr) (not (pair? xpr))))

(define (plist? xpr)
  (or (pnull? xpr) (pair? xpr)))

(define (plength pl)
  (let loop ((pl pl) (len 0))
    (if (pnull? pl)
      len
      (loop (cdr pl) (+ len 1)))))

(define (plist-tail pl n)
  (cond
    ((or (negative? n) (> n (plength pl)))
     (error 'plist-tail
            "out of range"
            pl n))
    ((zero? n) pl)
    (else
     (plist-tail (cdr pl) (- n 1)))))

(define (plist-ref pl n)
  (cond
    ((or (negative? n) (>= n (plength pl)))
     (error 'plist-ref
            "out of range"
            pl n))
    ((zero? n) (car pl))
    (else
     (plist-ref (cdr pl) (- n 1)))))

;;;; other helpers

(define (prefixed-with? pre)
  (lambda (id)
    (let ((pre-str (symbol->string pre))
          (id-str (symbol->string id)))
      (let ((pre-len (string-length pre-str)))
        (and (< pre-len (string-length id-str))
             (string=? pre-str
                       (substring id-str 0 pre-len)))))))

(define (add-prefix pre id)
  (string->symbol
    (string-append (symbol->string pre)
                   (symbol->string id))))

(define (strip-prefix pre id)
  (string->symbol
    (substring (symbol->string id)
               (string-length
                 (symbol->string pre)))))

(define (strip-suffix suf id)
  (let ((sufstring (symbol->string suf))
        (idstring (symbol->string id)))
    (string->symbol
      (substring idstring
                 0 
                 (- (string-length idstring)
                    (string-length sufstring))))))

(define (extract ok? tree)
  (remove-duplicates
    (filter ok? (flatten tree))))

(define (list-of? ok?)
  (lambda (lst)
    (not (memq #f (map ok? lst)))))

(define (atom? x)
  (not (pair? x)))

(define (map* fn . trees)
  (if (null? trees)
    '()
    (let loop ((trees trees))
      (cond
        (((list-of? pair?) trees)
         (cons (loop (map car trees)) (loop (map cdr trees))))
        (((list-of? null?) trees)
         '())
        (((list-of? atom?) trees)
         (apply fn trees))
        (else
          (error "not all of same structure" trees))))))

(define (flatten-map* fn . trees)
  (if (null? trees)
    '()
    (let loop ((trees trees))
      (cond
        (((list-of? pair?) trees)
         (append (loop (map car trees)) (loop (map cdr trees))))
        (((list-of? null?) trees)
         '())
        (((list-of? atom?) trees)
         (list (apply fn trees)))
        (else
          (error "not all of same structure" trees))))))

(define (replace* what? by tree)
  (let loop ((tree tree))
    (cond
      ((pair? tree)
       (cons (loop (car tree))
             (loop (cdr tree))))
      ((null? tree) tree)
      ((what? tree) (by tree))
      (else tree))))

(define (memp ok? lst)
  (let loop ((lst lst))
    (if (null? lst)
      #f
      (if (ok? (car lst))
        lst
        (loop (cdr lst))))))

(define (assp ok? tbl)
  (let loop ((tbl tbl))
    (cond
      ((null? tbl) #f)
      ((ok? (caar tbl)) (car tbl))
      (else (loop (cdr tbl))))))

(define (filter ok? lst)
  (let loop ((lst lst) (yes '()) (no '()))
    (if (null? lst)
      (values (reverse yes) (reverse no))
      (let ((first (car lst)) (rest (cdr lst)))
        (if (ok? first)
          (loop rest (cons first yes) no)
          (loop rest yes (cons first no)))))))

(define (flatten tree)
  (let loop ((tree tree) (result '()))
    (cond
      ((null? tree) result)
      ((not (pair? tree)) (cons tree result))
      (else
        (loop (car tree) (loop (cdr tree) result))))))

(define (remove-duplicates lst)
  (let loop ((lst lst) (result '()))
    (if (null? lst)
      (reverse result)
      (loop (cdr lst) (adjoin (car lst) result)))))

(define (adjoin obj lst)
  (if (member obj lst) lst (cons obj lst)))

(define (mappend fn lists) ; mapcan in CL
  (apply append (map fn lists)))

#|[
Now to the destructuring procdures. Note that destruc will return three
values, which are used by one of the other destructuring routines
respectively.
]|#

(define (destruc pat seq glen gref gtail)
  (let loop ((pat pat) (seq seq) (n 0))
    (if (pair? pat)
      (let ((p (car pat)))
        (receive (rec-ex rec-lit rec-len)
          (loop (cdr pat) seq (+ n 1))
          (if (or (pair? p) (null? p))
            (let ((g (gensym)) (v `(,gref ,seq ,n)))
              (receive (g-ex g-lit g-len) (loop p g 0)
                (values
                  (cons (cons `(,g (,gref ,seq ,n))
                              g-ex) rec-ex)
                  (cons (cons `(,g (,gref ,seq ,n))
                              g-lit) rec-lit)
                  (append (replace*
                            (lambda (x) (and (symbol? x) (eq? x g)))
                            (lambda (y) v)
                            g-len)
                          rec-len))))
            (if (symbol? p)
              (values
                (cons `(,p (,gref ,seq ,n)) rec-ex)
                rec-lit
                rec-len)
              (values
                rec-ex
                (cons `(,p (,gref ,seq ,n)) rec-lit)
                rec-len)))))
      (let ((tail `(,gtail ,seq ,n))
            (length-check (lambda (p s)
                            (if (list? p)
                              `(= (,glen ',p) (,glen ,s))
                              `(<= (,glen ',p) (,glen ,s))))))
        (if (null? pat)
          (values '() '() `(,(length-check pat tail)))
          (if (symbol? pat)
            (values `((,pat ,tail)) '() `(,(length-check pat tail)))
            (values '() `((,pat ,tail)) `(,(length-check pat tail)))))))))

#|[
Two exported versions of destruc
]|#

(define (list-destruc pat seq)
  (destruc pat seq 'plength 'plist-ref 'plist-tail))

(define (seq-destruc pat seq)
  (destruc pat seq 'seq-length 'seq-ref 'seq-tail))


#|[
Four procedures which use the results of destruc
]|#

;; to be called with destruc's first return value
(define (dbind-ex symbols body)
  (if (null? symbols)
    `(if ,(car body)
       (begin ,@(cdr body))
       (signal (bind-exception 'dbind-ex
                               "fenders not passed"
                               ',(car body))))
    `(let ,(map (lambda (b) (if (pair? (car b)) (car b) b))
                symbols)
       ,(dbind-ex
          (mappend (lambda (b) (if (pair? (car b)) (cdr b) '()))
                   symbols)
          body))))

;; to be called with destruc's second return value
(define (dbind-lit literals)
  (if (null? literals)
    #t
    (let ((pairs (map (lambda (b)
                        (if (pair? (car b))
                          (car b)
                          b))
                      literals)))
      (receive (syms lits)
        (filter (lambda (p) (symbol? (car p))) pairs)
        `(let ,syms
           (if (and ,@(map (lambda (s) (cons 'equal? s)) lits))
             ,(dbind-lit
                (mappend (lambda (b) (if (pair? (car b)) (cdr b) '()))
                         literals))
             (signal (bind-exception 'dbind-lit
                                     "literals don't match"
                                     ',lits))))))))

;; to be called with destruc's third return value
(define (dbind-len length-checks)
  `(condition-case (and ,@length-checks)
     ((exn)
      (signal (bind-exception 'dbind-len
                              "length-checks violated")))))

;; to be called with destruc's first return value
(define (dbind-def op binds)
  ;; Note, that gensyms don't pollute namespaces
  (if (null? binds)
    `(,op ,(gensym) (void))
    (let ((pairs (map (lambda (b)
                        (if (pair? (car b))
                          (car b)
                          b))
                      binds)))
      `(begin ,@(map (lambda (x) `(,op ,(car x) ,(cadr x)))
                     pairs)
              ,(dbind-def op
                          (mappend (lambda (b) (if (pair? (car b)) (cdr b) '()))
                                   binds))))))

;;; Please note, that these four helpers needn't care for renaming,
;;; since we'll implement dbind as an implicit renaming macro, which
;;; does the renaming automatically behind the scene. Even the gensym
;;; could be avoided by the same reason. But I prefer to have differnt
;;; names for repeated calls of a renaming procedure, which is
;;; guaranteed by gensym but violated by rename.


#|[ 
Now to the generic functions seq-ref, seq-tail and seq-length which can
be used as additional arguments in destruc, provided they are imported
for-syntax.
The following two macros help to avoid repetition of code.
]|#

(define-syntax search-and-call
  (syntax-rules ()
    ((_ tbl)
     (lambda args
       (let ((pair (assp (lambda (x) (x (car args)))
                         tbl))) ; choose method
         (if pair
           (apply (cdr pair) args) ; apply it
           (error 'search-and-call "type error" args)))))))

(define-syntax add-to-table
  (syntax-rules ()
    ((_ tbl)
     (lambda (pair)
       ;; pair must be added to the front
       ;; since last query of tbl, plist?,
       ;; is always #t
       (set! tbl (cons pair tbl))))))

#|[

Generic functions are in fact closures, which search a table for a
matching operation and apply that operation in case of a match.
To be able to add new operations to that table, we must get a handle on
it. In other words, there must be other routines which operate on the
same table. define-values will come to the rescue ...
]|#

(define-values (seq-length seq-length!)
  (let ((table
          (list
            (cons vector? vector-length)
            (cons string? string-length)
            ;; must be last, because plist? is always #t
            (cons plist? plength))))
    (values
      (search-and-call table)
      (add-to-table table))))

(define-values (seq-ref seq-ref!)
  (let ((table
          (list
            (cons vector? vector-ref)
            (cons string? string-ref)
            ;; must be last, because plist? is always #t
            (cons plist? plist-ref))))
    (values
      (search-and-call table)
      (add-to-table table))))

;; Chicken's subvector is buggy
(define (vector-tail seq n)
  (if (or (negative? n) (> n (vector-length seq)))
    (error 'vector-tail
           "out of range"
           n seq)
    (let* ((len (vector-length seq))
           (vec (make-vector (- len n) #f)))
      (do ((k n (+ k 1)))
        ((= k len) vec)
        (vector-set! vec (- k n) (vector-ref seq k))))))
    
(define-values (seq-tail seq-tail!)
  (let ((table
          (list
            (cons vector? vector-tail)
            (cons string? substring)
            ;; must be last, because plist? is always #t
            (cons plist? plist-tail))))
    (values
      (search-and-call table)
      (add-to-table table))))

#|[ 
Instead of exporting the three mutators above we export the following
one which updates all three local tables of the accessors in one go.
This way it's impossible to forget updating one of the three tables.
]|#

;;; (seq-length-ref-tail! type? type-length type-ref type-tail)
;;; -----------------------------------------------------------
;;; updates the tables with tree functions in this order and index it
;;; with the type predicate type?.
(define (seq-length-ref-tail! type? type-length type-ref type-tail)
  (seq-length! (cons type? type-length))
  (seq-ref!    (cons type? type-ref))
  (seq-tail!   (cons type? type-tail)))

) ; module macro-helpers

#|[
Low-level-macros made easy
==========================
As an application of our binding macros, especially bind and bind-case,
we will now provide macros define-macro, letrec-macro and let-macro as
well as macro-rules to make writing low-level macros easy.
]|#

(module low-level-macros 
  (export low-level-macros
          list-bind list-bind-case define-er-macro
          macro-rules define-macro let-macro letrec-macro
          list-bindrec list-set! list-define list-bind*
          once-only with-gensyms define-syntax-rule)
  (import scheme
          (only macro-helpers
                replace*
                bind-exception symbol-dispatcher)
          (only chicken
                condition-case
                print
                current-exception-handler
                make-property-condition
                condition-predicate
                get-condition-property
                signal
                abort))
  (reexport (only macro-helpers
                  bind-exception
                  list-destruc
                  plength plist-ref plist-tail))

  (import-for-syntax (only macro-helpers
                           extract
                           prefixed-with? strip-prefix
                           list-destruc
                           mappend
                           replace*
                           map*
                           flatten-map*
                           dbind-def
                           dbind-len
                           dbind-lit
                           dbind-ex)
                     (only chicken
                           receive condition-case))

(define low-level-macros
  (symbol-dispatcher '(
    (list-define
      macro:
      (list-define pat seq)
      "defines multiple variables by destructuring its nested list argument")
    (list-set!
      macro;
      (list-set! pat seq)
      "sets multiple variables by destructuring its nested list argument")
    (list-bind
      macro:
      (list-bind pat seq (where . fenders) .. xpr ....)
      "binds pattern variables of pat"
      "to corresponding values of seq"
      "checking matching literals and fenders"
      "and executes xpr .... in this context")
    (list-bind*
      macro:
      (list-bind* name pat seq (where . fenders) .. xpr ....)
      "named version of list-bind")
    (list-bindrec
      macro:
      (list-bindrec pat seq (where . fenders) .. xpr ....)
      "recursive version of list-bind")
    (list-bind-case
      macro:
      (list-bind-case seq (pat (where . fenders) .. xpr ....) ...)
      "executes"
      "(bind pat seq (where . fenders) ..) xpr ....) ..."
      "in a case fashion")
    (macro-rules
      macro:
      (macro-rules literal ... (keyword ...) (pat tpl) ....)
      "low-level version of syntax-rules"
      "with optional injected literals"
      "and quasiquoted templates")
    (define-er-macro
      macro:
      (define-er-macro (name . args) (rename-prefix pre) (keywords key ...) .. xpr ....)
      "explicit-renaming macro where prefixed symbols are renamed")
    (define-macro
      macro:
      one-of
      (define-macro (name . args) xpr ....)
      (define-macro (name . args) (keywords x ...) xpr ....)
      (define-macro (name . args) (inject y ...) xpr ....)
      (define-macro (name . args) (inject y ...) (keywords x ...) xpr ....)
      (define-macro (name . args) (keywords x ...) (inject y ...) xpr ....)
      "a version of macro-rules with only one rule")
    (let-macro
      macro:
      (let-macro ((code tpl) ...) xpr ....) 
      "local parallel version of define-macro")
    (letrec-macro
      macro:
      (letrec-macro ((code tpl) ...) xpr ....) 
      "local recursive version of define-macro")
    (once-only
      macro:
      (once-only (x ....) xpr ....)
      "arguments x ... are evaluated only once")
    (with-gensyms
      macro:
      (with-gensyms (x ....) xpr ....)
      "generates a series of gensyms x .... to be used in xpr ...")
    (define-syntax-rule
      macro:
      one-of
      (define-syntax-rule (name . args) tpl)
      (define-syntax-rule (name . args) (keywords x ...) tpl)
      "syntax-rules with only one rule")
    )))


;;; set parameter current-exception-handler to handle bind-exceptions
(current-exception-handler
  (let ((old-handler (current-exception-handler)))
    (lambda (var)
      (if ((condition-predicate 'bind) var)
        (begin
          (display "Error: ")
          (print (get-condition-property var 'bind 'location))
          (print (get-condition-property var 'bind 'message))
          (for-each print (get-condition-property var 'bind 'arguments))
          (abort (make-property-condition 'exn
                   'message "exception-handler returned")))
        (old-handler var)))))

#|[ 
The first two macros are nested versions of set! and define. They allow
the simultaneous definition of procedures which have access to common
state. In fact, it suffices to implement bind-set! since Chicken
reduces define to set! anyway: try (expand '(define a 1)) to convince
yourself.  So we could implement bind-define as an alias to bind-set!
But according to the standard, set! changes existing variables, while
define defines new ones. So our definition will reflect this.

bind-set! replaces the values of symbols in a nested lambda-list in one
go with the corresponding subeseqessions of its second argument. So,
after (bind-set! (a (b (c . d))) '(1 (2 (3 4 5)))) d should have the
value (4 5), b the value 2 etc.
bind-define does the same, but defines the pattern variables before
setting them. The real advantage of this is, that we can define several
functions which rely on the same encapsulated state. Consider

  (bind-define (push top pop)
    (let ((state '()))
      (list
        (lambda (arg) (set! lst (cons arg state)))
        (lambda () (car state))
        (lambda () (set! lst (cdr state))))))

Now we have three procedures, which all operate on the encapsulated
list.

The implementation uses the fourth procedure, dbind-def, which operates
on the return values of seq-destruc.
]|#

;;; (list-define pat seq)
;;; ---------------------
;;; destructures the nested list seq according to pat and sets pattern
;;; variables with values corresponding to subexpressions of seq
(define-syntax list-define
  (ir-macro-transformer
    (lambda (form inject compare?)
      (let ((pat (cadr form)) (seq (caddr form)) (gseq 'seq))
        `(begin (define ,gseq ,seq)
                ,(dbind-def 'define (list-destruc pat gseq)))))))

;;; (list-set! pat seq)
;;; -------------------
;;; destructures the nested list seq according to pat and defines
;;; pattern variables with values corresponding to subexpressions of seq
(define-syntax list-set!
  (ir-macro-transformer
    (lambda (form inject compare?)
      (let ((pat (cadr form)) (seq (caddr form)) (gseq 'seq))
        `(begin (set! ,gseq ,seq)
                ,(dbind-def 'set! (list-destruc pat gseq)))))))

#|[
Now we'll extend Graham's dbind, allowing non-symbols in the patterns,
which must be equal to the corresponding values in the template for a
match.
]|#

(define-syntax dbind
  (ir-macro-transformer
    (lambda (form inject compare?)
      (let ((pat (cadr form))
            (seq (caddr form))
            (body (cdddr form))
            (gseq 'seq))
        `(let ((,gseq ,seq))
           ,(receive (symbols literals checks)
              (list-destruc pat seq)
              `(if ,(dbind-len checks)
                 (if ,(dbind-lit literals)
                   ,(dbind-ex symbols body)
                   (signal
                     (bind-exception 'dbind
                                     "literals don't match"
                                     ',literals)))
                 (signal (bind-exception 'dbind
                                         "not matchable"
                                         ',pat ,gseq)))))))))
     
;;; (list-bind pat seq (where . fenders) .. xpr ....)
;;; -------------------------------------------------
;;; binds pattern variables of pat to corresponding subexpressions of
;;; seq and executes tthe body xpr .... in this context. If a where
;;; expression is supplied, all fenders must return #t for seq to be
;;; successfully bound.
(define-syntax list-bind
  (syntax-rules (where)
    ((_ pat seq (where . fenders) xpr . xprs)
     (dbind pat seq (and . fenders) xpr . xprs))
    ((_ pat seq xpr . xprs)
     (dbind pat seq #t xpr . xprs))))

#|[
The macro list-bind* is to list-bind what named let is to let. It takes an
additional argument besides those of list-bind, which is bound to a
recursive procedure, which can be called in list-bind's body. The
pattern variables are initialised with the corresponding subexpressins
in seq. For example

  (list-bind* loop (x y) '(5 0)
    (if (zero? x)
      (list x y)
      (loop (list (sub1 x) (add1 y)))))
  -> '(0 5)
]|#

;;; (list-bind* name pat seq (where . fenders) .. xpr . xprs)
;;; ---------------------------------------------------------
;;; named version of bind
(define-syntax list-bind*
;  (ir-macro-transformer
;    (lambda (form inject compare?)
;      (let ((name (cadr form))
;            (pat (caddr form))
;            (seq (cadddr form))
;            (body (cddddr form)))
;        `((letrec ((,name 
;                     (lambda (x)
;                       (dbind ,pat x ,@body))))
;            ,name)
;          ,seq)))))
  (syntax-rules (where)
    ((_ loop pat seq (where . fenders) xpr . xprs)
     ((letrec ((loop 
                 (lambda (x)
                   (list-bind pat x (where . fenders) xpr . xprs))))
        loop)
      seq))
    ((_ loop pat seq xpr . xprs)
     (list-bind* loop pat seq (where) xpr . xprs))))

;;; (list-bindrec pat seq (where . fenders) .. xpr ....)
;;; ----------------------------------------------------
;;; recursive version of list-bind
(define-syntax list-bindrec
  ;; syntax-rules doesn't work
  (ir-macro-transformer
    (lambda (form inject compare?)
      (let ((pat (cadr form))
            (seq (caddr form))
            (xpr (cadddr form))
            (xprs (cddddr form)))
        (let ((aux (map* gensym pat)))
          `(let ,(flatten-map* (lambda (v) `(,v #f)) pat)
             (dbind ,aux ,seq
               ,@(flatten-map* (lambda (x y) `(set! ,x ,y))
                               pat aux)
               (if ,(and (pair? xpr) (compare? (car xpr) 'where))
                 (if (and ,@(cdr xpr))
                   (begin ,@xprs)
                   (signal (bind-exception 'list-bindrec
                                           "fenders not passed"
                                           ',(cdr xpr))))
                 (begin ,xpr ,@xprs)))))))))

;;; (list-bind-case seq (pat (where . fenders) .. xpr . xprs) ....)
;;; ---------------------------------------------------------------
;;; Checks if seq matches pattern pat [satisfying fenders] ....
;;; in sequence, binds the pattern variables of the first matching
;;; pattern to corresponding subexpressions of seq and executes
;;; corresponding body xpr . xprs
(define-syntax list-bind-case
  (syntax-rules (where)
    ((_ seq (pat (where . fenders) xpr . xprs) . clauses)
     (condition-case (dbind pat seq (and . fenders) xpr . xprs)
       ((exn bind) (list-bind-case seq . clauses))))
    ((_ seq (pat xpr . xprs) . clauses)
     (condition-case (dbind pat seq #t xpr . xprs)
       ((exn bind) (list-bind-case seq . clauses))))
    ((_ seq)
     (signal (bind-exception 'list-bind-case
                             "no rule matches"
                             seq)))
    ))
;;; (macro-rules sym ... (key ...)
;;;   (pat tpl) ....)
;;; ------------------------------
;;; where sym ... are injected non-hygienig symbols, key ... are
;;; additional keywords, pat ....  are nested lambda-lists without
;;; spezial meaning of ellipses and tpl .... evaluate to
;;; quasiquoted templates.
(define-syntax macro-rules
  (ir-macro-transformer
    (lambda (f i c?)
      ;; injections is list of injected syms, tail starts with keyword-list
      (receive (tail injections)
        (let loop ((tail (cdr f)) (injections '()))
          (if (list? (car tail)) ; keyword list
            (values tail injections)
            (loop (cdr tail) (cons (car tail) injections))))
          (let ((keywords (car tail)) (rules (cdr tail)))
            (if (null? rules)
              `(signal (bind-exception 'macro-rules "no rule matches"))
              (let (
                (inject-sym (lambda (h) `(,h (inject ',h))))
                (extract-keywords
                  (lambda (r) (extract (lambda (y) (memq y keywords)) r)))
                )
                (let (
                  (process-rule
                    (lambda (r)
                      `(,(car r)
                         (and ,@(map (lambda (p s) `(compare? ,p ,s))
                                       (extract-keywords (cadar r))
                                       (map (lambda (x) `',x)
                                            (extract-keywords (cadar r)))))
                         ,(cadr r))))
                  )
                  (cond
                    ((and (null? injections) (null? keywords))
                     ; no injected symbols, no additional keywords
                     `(ir-macro-transformer
                        (lambda (form inject compare?)
                          (list-bind-case form ,@rules))))
                    ((null? injections)
                     ; no injected symbols
                     `(ir-macro-transformer
                        (lambda (form inject compare?)
                          (list-bind-case form
                            ,@(map process-rule rules)))))
                    ((null? keywords)
                     ;; no additional keywords
                     `(ir-macro-transformer
                        (lambda (form inject compare?)
                          (let ,(map inject-sym injections)
                            (list-bind-case form ,@rules)))))
                    (else ; both injected symbols and additional keywords
                      `(ir-macro-transformer
                         (lambda (form inject compare?)
                           (let ,(map inject-sym injections)
                             (list-bind-case form
                               ,@(map process-rule rules)))))))))))))))

;;; (define-macro (name . args)
;;;   (inject sym ...) ..
;;;   (keywords key ...) ..
;;;   xpr ....)
;;; ---------------------------
(define-syntax define-macro
  (syntax-rules (inject keywords)
    ((_ (name . args) (inject sym ...) (keywords key ...) xpr . xprs)
     (define-syntax name
       (macro-rules sym ... (key ...) ((_ . args) xpr . xprs))))
    ((_ (name . args) (keywords key ...) (inject sym ...) xpr . xprs)
     (define-syntax name
       (macro-rules sym ... (key ...) ((_ . args) xpr . xprs))))
    ((_ (name . args) (inject sym ...) xpr . xprs)
     (define-syntax name
       (macro-rules sym ... () ((_ . args) xpr . xprs))))
    ((_ (name . args) (keywords key ...) xpr . xprs)
     (define-syntax name
       (macro-rules (key ...) ((_ . args) xpr . xprs))))
    ((_ (name . args) xpr . xprs)
     (define-syntax name
       (macro-rules () ((_ . args) xpr . xprs))))))

;;; (define-er-macro (name . args)
;;;   (rename-prefix pre)
;;;   (keywords key ...) ..
;;;   xpr ....)
;;; ------------------------------
(define-syntax define-er-macro
  (ir-macro-transformer
    (lambda (f i c?)
      (let ((pat (cadr f)) (pre (cadr (caddr f))) (body (cdddr f)))
        (let* (
          (keywords? (c? (car body) 'keywords))
          (body (if keywords? (cdr body) body))
          )
          (let (
            (process
              (lambda (p keys)
                (map (lambda (x y) `(compare? ,x ,y))
                     (extract (lambda (a) (memq a keys)) (cdr p))
                     (map (lambda (b) `',b)
                          (extract (lambda (a) (memq a keys)) (cdr p))))))
            )
            (if keywords?
              (let ((keys (cadr body)))
                `(define-syntax ,(car pat)
                   (er-macro-transformer
                     (lambda (form rename compare?)
                       (condition-case
                         (list-bind ,(cdr pat) (cdr form)
                           (where ,@(process (cdr pat) keys))
                           (let ,(map (lambda (s)
                                        `(,s (rename
                                               ',(strip-prefix (i pre)
                                                               (i s)))))
                                      (extract (prefixed-with? (i pre))
                                               body))
                             ,@body))
                         ((exn bind)
                          (signal (bind-exception 'define-macro
                                                  "no match")))))))))
              `(define-syntax ,(car pat)
                 (er-macro-transformer
                   (lambda (form rename compare?)
                     (condition-case
                       (list-bind ,(cdr pat) (cdr form)
                         (let ,(map (lambda (s)
                                      `(,s (rename
                                             ',(strip-prefix (i pre)
                                                             (i s)))))
                                    (extract (prefixed-with? (i pre))
                                             body))
                           ,@body))
                       ((exn bind)
                        (signal (bind-exception 'define-macro
                                                "no match")))))))
              ))))))

;;; (letrec-macro ((macro-code tpl) ...) . body)
;;; --------------------------------------------
;;; defines local macros by binding recursively macro-codes to templates
;;; and evaluating body in this context.
(define-syntax letrec-macro
  (er-macro-transformer
    (lambda (f r c?)
      (let ((binds (cadr f))
            (body (cddr f))
            (%letrec-syntax (r 'letrec-syntax)))
        `(,%letrec-syntax
           ,(map (lambda (m)
                   `(,(cadr m) ,(caddr m)))
                 (map (lambda (b)
                        (expand `(define-macro ,@b)))
                      binds))
           ,@body)))))

;;; (let-macro ((macro-code tpl) ...) . body)
;;; -----------------------------------------
;;; defines local macros by binding in parallel macro-codes to templates
;;; and evaluating body in this context.
(define-syntax let-macro
  (er-macro-transformer
    (lambda (f r c?)
      (let ((binds (cadr f))
            (body (cddr f))
            (%let-syntax (r 'let-syntax)))
        `(,%let-syntax
           ,(map (lambda (m)
                   `(,(cadr m) ,(caddr m)))
                 (map (lambda (b)
                        (expand `(define-macro ,@b)))
                      binds))
           ,@body)))))

#|[
The following three macros are here for convenience. The first two are
of great help in writing low-level-macros, the last ony simplifies
high-level macros without additional keywords and only one rule - it's
defined in miscmacros as well.
]|#

;;; (once-only (x ...) . body)
;;; --------------------------
;;; macro-arguments x ... are only evaluated once and from left to right
(define-syntax once-only  ; ok
  (er-macro-transformer
    (lambda (form rename compare?)
      (let ((names (cadr form))
            (body (cddr form))
            (%let (rename 'let))
            (%list (rename 'list))
            (%gensym (rename 'gensym)))
        (let ((gensyms (map gensym names)))
          `(,%let ,(map (lambda (g) `(,g (,%gensym))) gensyms)
             (,%list ',%let ,(cons %list
                               (map (lambda (g n) `(,%list ,g ,n))
                                    gensyms names))
                (,%let ,(map (lambda (n g) `(,n ,g)) names gensyms)
                   ,@body))))))))

;;; (with-gensyms (name ...) . body)
;;; --------------------------------
;;; binds name ... to (gensym 'name) ... in body
(define-syntax with-gensyms
  (ir-macro-transformer
    (lambda (form inject compare?)
      `(let ,(map (lambda (n) `(,n (gensym ',n))) (cadr form))
         ,@(cddr form)))))

;;; (define-syntax-rule (name . args) (keywords . keys) .. tpl)
;;; -----------------------------------------------------------
;;; simplyfies define-syntax in case there are no auxiliary keywords
;;; and only one syntax-rule.
(define-syntax define-syntax-rule
  (syntax-rules (keywords)
    ((_ (name . args)
        (keywords key ...) tpl)
     (define-syntax name
       (syntax-rules (key ...)
         ((_ . args) tpl))))
    ((_ (name . args) tpl)
     (define-syntax name
       (syntax-rules ()
         ((_ . args) tpl))))))

) ; module low-level-macros

;(use simple-tests)
;(import macro-helpers low-level-macros)
;(import-for-syntax macro-helpers (only low-level-macros macro-rules))