stim_amp=0.01875

// object variable will refer to a list that will hold an arbitrary number of NetCon objects.

objectvar nclist  

// synapses         

objectvar synAMPA,synNMDA,synGABAa1,synGABAa2 

//counting spikes

objref spiketimes,spikecount

objref voltagem

tmax=1000   

create soma

x=0
y=0
z=0

spiketimes=new Vector()
lastspikecount=0

voltagem=new Vector()

soma {

    pt3dclear()
    pt3dadd(x,y,z,10)  //set position of cell
    pt3dadd(x,y,z+10,10)
     
    nseg=1
    diam=11.8
    L=11.8 
    Ra=100
    cm=1
    celsius = 30
    
    Area = PI*soma.diam*soma.L*1e-8

    insert CGC_CaHVA
    insert CGC_ca
    insert CGC_KA
    insert CGC_KCa
    insert CGC_Kir    
    insert CGC_KM
    insert CGC_KV 
    insert CGC_Lkg1 
    insert CGC_Lkg2
    insert CGC_Na
    
    ena = 87.39
    ek = -84.69
    eca = 129.33
    ecl = -65
    
    nclist=new List()
    
    //Synapses
    synAMPA=new Exp2Syn(0.5) //Adding synapse with rise and decay time
    synAMPA.tau1=0.03  // ms rise time 
    synAMPA.tau2=0.5  // ms decay time 
    synAMPA.e=0     // mV reversal potential 
    
    synNMDA=new Exp2Syn(0.5) //Adding synapse with rise and decay time
    synNMDA.tau1=1  // ms rise time
    synNMDA.tau2=13.3  // ms decay time 
    synNMDA.e=0     // mV reversal potential 
    
    synGABAa1=new Exp2Syn(0.5) //Adding synapse with rise and decay time
    synGABAa1.tau1=0.31  // ms rise time 
    synGABAa1.tau2=8.8  // ms decay time 
    synGABAa1.e=-75     // mV reversal potential 
    
    synGABAa2=new Exp2Syn(0.5) //Adding synapse with rise and decay time
    synGABAa2.tau1=0.31  // ms rise time 
    synGABAa2.tau2=300  // ms decay time 
    synGABAa2.e=-75     // mV reversal potential 
    
    //counting spikes
    spikecount=new APCount(0.5)
    spikecount.thresh=-20
    spikecount.record(spiketimes)
    
    //Saving Vm
    voltagem.record(&v(0.5))
}