;;;; message-digest-port.scm  -*- Scheme -*-
;;;; Kon Lovett, Jul '18
;;;; Kon Lovett, Aug '17
;;;; Kon Lovett, May '10

;; Issues
;;
;; - Use of sys namespace routines.

(declare
  (bound-to-procedure
    ##sys#slot ##sys#setslot
    ##sys#port-data ##sys#set-port-data!))

(module message-digest-port

(;export
  digest-output-port? check-digest-output-port error-digest-output-port
  digest-output-port-name
  open-output-digest
  get-output-digest
  call-with-output-digest
  with-output-to-digest)

(import scheme
  (chicken base)
  (chicken fixnum)
  (chicken type)
  (only (chicken string) ->string)
  (only (chicken port) make-output-port with-input-from-port)
  (only (srfi 13) string-suffix-length-ci)
  (only type-checks define-check+error-type check-output-port)
  (only type-errors error-argument-type make-error-type-message signal-type-error)
  message-digest-primitive
  message-digest-type
  message-digest-byte-vector)

;;; Support

;;fx-utils

(: fxpositive? (fixnum --> boolean))
;
(define (fxpositive? n)
  (fx< 0 n) )

;;

(include "message-digest-types")

;;

(define PORT-TAG 'digest)

(define PRIMITIVE-NAME-SUFFIXES '("p" "-primitive"))

;;% for primitive

(define (%port-type p)
  (##sys#slot p 7) )

(define (%port-type-set! p t)
  (##sys#setslot p 7 t) )

(define (%port-name p)
  (##sys#slot p 3) )

(define (%set-port-name! p s)
  (##sys#setslot p 3 s) )

(define (%port-data p)
  (##sys#port-data p) )

(define (%set-port-data! p s)
  (##sys#set-port-data! p s) )

;;

(define (check-open-port loc obj #!optional argnam)
  (if (port-closed? obj)
    (error-argument-type loc obj "open port" argnam)
    obj ) )

(define (check-open-digest-output-port loc obj #!optional argnam)
  (let (
    (port (%port-type (check-open-port loc (check-output-port loc obj argnam) argnam))) )
    (unless (eq? PORT-TAG port)
      (signal-type-error loc (make-error-type-message 'digest-output-port) obj argnam) ) )
  obj )

;Synthesize a port-name from a primitive-name
(: make-digest-port-name (message-digest-primitive --> string))
;
(define make-digest-port-name
  ;need byte-oriented semantics
  (let ((substring substring))
    (lambda (mdp)
      (let* (
        (nam
          (->string (or (message-digest-primitive-name mdp) 'md)))
        ;strip trailing (why ?)
        (remlen
          ;longest suffix length or negative
          (foldl
            (lambda (remlen suf)
              (fxmax remlen (string-suffix-length-ci nam suf)) )
            -1
            PRIMITIVE-NAME-SUFFIXES))
        (nam
          (if (fxpositive? remlen)
            (substring nam 0 (fx- (string-length nam) remlen))
            nam)) )
        (string-append "(" nam ")") ) ) ) )

;;; Message Digest Output Port API

(: open-output-digest (message-digest-primitive -> digest-output-port))
;
(define (open-output-digest mdp)
  (let* (
    (md
      (initialize-message-digest mdp))
    (writer
      (lambda (obj)
        ;for now only a string
        (if (string? obj)
          (message-digest-update-string md obj)
          (message-digest-update-blob md obj))))
      ;use default close behavior
      (port
        (make-output-port writer void)) )
    (%set-port-data! port md)
    (%port-type-set! port PORT-TAG)
    (%set-port-name! port (make-digest-port-name mdp))
    port ) )

(: digest-output-port? (* -> boolean : digest-output-port))
;
(define (digest-output-port? obj)
  (and
    (output-port? obj)
    (eq? PORT-TAG (%port-type obj)) ) )

(define-check+error-type digest-output-port)

(: digest-output-port-name (digest-output-port --> string))
;
(define (digest-output-port-name port)
  (%port-name (check-digest-output-port 'digest-output-port-name port)) )

(: *close-output-digest (symbol digest-output-port message-digest-result-form -> message-digest-result-type))
;
(define (*close-output-digest loc port restyp)
  (let (
    ;must be restyp
    (res '||) )
    (dynamic-wind
      (lambda ()
        (set! res
          (finalize-message-digest
            (%port-data (check-open-digest-output-port loc port 'digest-port))
            restyp)))
      (lambda ()
        res)
      (lambda ()
        (close-output-port port))) ) )

(: get-output-digest (digest-output-port #!rest -> message-digest-result-type))
;
(define (get-output-digest port . opts)
  (let (
    (restyp (optional opts (message-digest-result-form))) )
    (*close-output-digest 'get-output-digest port restyp) ) )

;;;

(: call-with-output-digest (message-digest-primitive procedure #!rest -> message-digest-result-type))
;
(define (call-with-output-digest mdp proc . opts)
  (let (
    (restyp (optional opts (message-digest-result-form))) )
    (let (
      (port #f) )
      (dynamic-wind
        (lambda () (set! port (open-output-digest mdp)))
        (lambda () (proc port))
        (lambda () (*close-output-digest 'call-with-output-digest port restyp))) ) ) )

(: with-output-to-digest (message-digest-primitive procedure #!rest -> message-digest-result-type))
;
(define (with-output-to-digest mdp thunk . opts)
  (let (
    (restyp (optional opts (message-digest-result-form))) )
    (call-with-output-digest mdp (cut with-input-from-port <> thunk) restyp) ) )

) ;module message-digest