;;;; message-digest-support.scm  -*- Scheme -*-
;;;; Kon Lovett, Jul '18
;;;; Kon Lovett, Aug '17
;;;; Kon Lovett, Apr '12
;;;; Kon Lovett, May '10 (message-digest.scm)
;;;; Kon Lovett, Jan '06 (message-digest.scm)

;; Issues
;;
;; - Uses 'context-info' to determine whether active context is "own" allocation or
;; callers. Again, a kludge.
;;
;; - Passes u8vector to update phase as a blob.

(module message-digest-support

(;export
  ;Support
  packed-vector->blob/shared
  ;
  u8vector/slice blob/slice string/slice
  ;
  *message-digest-update-blob
  *message-digest-update-string)

(import scheme
  (chicken base)
  (chicken blob)
  (chicken fixnum)
  (chicken type)
  (only (chicken memory representation) number-of-bytes)
  (only srfi-4
    s8vector? u8vector? subu8vector u8vector-length
    s16vector? u16vector?
    s32vector? u32vector?
    u64vector? s64vector?
    f32vector? f64vector?
    s8vector->blob/shared u8vector->blob/shared
    s16vector->blob/shared u16vector->blob/shared
    s32vector->blob/shared u32vector->blob/shared
    s64vector->blob/shared u64vector->blob/shared
    f32vector->blob/shared f64vector->blob/shared)
  message-digest-primitive
  message-digest-type)

;;; Support

;;

(include "message-digest-types")

;;

(define-type start-index fixnum)
(define-type end-index (or boolean fixnum))

;;fx-utils

(: fxzero? (fixnum --> boolean))
;
(define (fxzero? n)
  (fx= 0 n) )

;;

;Used by update-item & srfi-4 modules

(: packed-vector->blob/shared (srfi4vector -> (or boolean blob)))
;
(define (packed-vector->blob/shared obj)
  (cond
    ((u8vector? obj)        (u8vector->blob/shared obj))
    ((s8vector? obj)        (s8vector->blob/shared obj))
    ((u16vector? obj)       (u16vector->blob/shared obj))
    ((s16vector? obj)       (s16vector->blob/shared obj))
    ((u32vector? obj)       (u32vector->blob/shared obj))
    ((s32vector? obj)       (s32vector->blob/shared obj))
    ((u64vector? obj)       (u64vector->blob/shared obj))
    ((s64vector? obj)       (s64vector->blob/shared obj))
    ((f32vector? obj)       (f32vector->blob/shared obj))
    ((f64vector? obj)       (f64vector->blob/shared obj))
    (else
      #f ) ) )

;;

(: u8vector/slice (u8vector start-index end-index --> u8vector))
;
(define (u8vector/slice u8vec start end)
   (let (
    (end (or end (u8vector-length u8vec))) )
    (if (and (fx= end (u8vector-length u8vec)) (fxzero? start))
      u8vec
      (subu8vector u8vec start end) ) ) )

(: blob/slice (blob start-index end-index --> blob))
;
(define blob/slice
  ;need byte-oriented semantics
  (let ((substring substring))
    (lambda (blb start end)
      (let (
        (end (or end (blob-size blb))) )
        (if (and (fx= end (blob-size blb)) (fxzero? start))
          blb
          (string->blob (substring (blob->string blb) start end)) ) ) ) ) )

(: string/slice (string start-index end-index --> string))
;
(define (string/slice str start end)
  (let (
    (end (or end (string-length str))) )
    (if (and (fx= end (string-length str)) (fxzero? start))
      str
      (substring str start end) ) ) )

;;

(: *message-digest-update-blob (message-digest blob #!rest -> void))
;
(define (*message-digest-update-blob md blb . opts)
  (let (
    (siz (optional opts (blob-size blb))) )
    ((message-digest-algorithm-update md) (message-digest-context md) blb siz) ) )

(: *message-digest-update-string (message-digest string -> void))
;
(define (*message-digest-update-string md str)
	(*message-digest-update-blob md (string->blob str)) )

(: message-digest-algorithm-update (message-digest -> procedure))
;
(define (message-digest-algorithm-update md)
  (message-digest-primitive-update (message-digest-algorithm md)) )

) ;module message-digest-support