;;;; symbol-name-utils.scm  -*- Scheme -*-
;;;; Kon Lovett, Jul '18

(module symbol-name-utils

(;export
  keyword->symbol
  keyword->uninterned-symbol
  symbol->keyword
  symbol-printname-details
  symbol-printname=? symbol-printname<?
  symbol-printname-length
  max-symbol-printname-length)

(import scheme
  (chicken base)
  (chicken keyword)
  (chicken fixnum)
  (chicken type)
  (only type-checks check-symbol check-list))

;;; Support

;;

(: exploded-qualified-symbol=? (string string string string --> boolean))
;
(define (exploded-qualified-symbol=? px sx py sy)
  (and (string=? px py) (string=? sx sy)) )

(: exploded-qualified-symbol<? (string string string string --> boolean))
;
(define (exploded-qualified-symbol<? px sx py sy)
  (or
    (and (string=? px py) (string<? sx sy))
    (string<? px py)) )

;;;

;;

(: keyword->symbol (symbol --> symbol))
;
(define (keyword->symbol kwd)
  (string->symbol (keyword->string kwd)) )

(: keyword->uninterned-symbol (symbol --> symbol))
;
(define (keyword->uninterned-symbol kwd)
  (string->uninterned-symbol (keyword->string kwd)) )

;;

;symbol->string drops namespace qualification!
;which means a keyword and a symbol of the same name have the same printname.

(: symbol->keyword (symbol --> symbol))
;
(define (symbol->keyword sym)
  (if (keyword? sym)
    sym
    (string->keyword (symbol->string (check-symbol 'symbol->keyword sym))) ) )

;;

(: *symbol-printname-details (symbol --> string string))
;
(define (*symbol-printname-details sym)
  (values (symbol->string sym) "")
#;
  (let ((p (##sys#qualified-symbol-prefix sym)))
    (values
      (symbol->string sym)
      (cond
        ((not p)                      "" )
        ((eq? #\x0 (string-ref p 0))  ":")
        (else                         (substring p 1) ) ) ) ) )

(: symbol-printname-details (symbol --> string string))
;
(define (symbol-printname-details sym)
  (let-values (
    ((s p) (*symbol-printname-details (check-symbol 'symbol-printname-details sym))))
    ;do not expose the symbol's "raw" printname
    (values (string-copy s) p) ) )

(: symbol-printname=? (symbol symbol --> boolean))
;
(define (symbol-printname=? x y)
  (let-values (
    ((sx px) (*symbol-printname-details (check-symbol 'symbol-printname=? x)))
    ((sy py) (*symbol-printname-details (check-symbol 'symbol-printname=? y))) )
    (exploded-qualified-symbol=? px sx py sy) ) )

(: symbol-printname<? (symbol symbol --> boolean))
;
(define (symbol-printname<? x y)
  (let-values (
    ((sx px) (*symbol-printname-details (check-symbol 'symbol-printname<? x)))
    ((sy py) (*symbol-printname-details (check-symbol 'symbol-printname<? y))) )
    (exploded-qualified-symbol<? px sx py sy) ) )

;;

(: symbol-printname-length (symbol --> fixnum))
;
(define (symbol-printname-length sym)
  (let (
    (len (string-length (symbol->string (check-symbol 'symbol-printname-length sym)))) )
    (if (keyword? sym)
      (fx- len 2) ;compensate for leading '###' when only a ':' is printed
      len ) ) )

(: max-symbol-printname-length ((list-of symbol) --> fixnum))
;
(define (max-symbol-printname-length syms)
  (if (null? (check-list 'max-symbol-printname-length syms))
    '()
    (apply max (map symbol-printname-length syms)) ) )

) ;module symbol-name-utils