;;;; symbol-name-utils.scm  -*- Scheme -*-
;;;; Kon Lovett, Jul '18

(module symbol-name-utils

(;export
  keyword->symbol
  keyword->uninterned-symbol
  symbol->keyword
  symbol-printname-details
  symbol-printname=? symbol-printname<?
  symbol-printname-length
  max-symbol-printname-length)

(import scheme
  (chicken base)
  (chicken keyword)
  (chicken fixnum)
  (chicken type)
  (only type-checks check-symbol check-list))

;;

(cond-expand
  (chicken-5.0 (define-type keyword symbol))
  (chicken-5.1)
  (else))

;;; Support

;;

(: exploded-qualified-symbol=? (string string string string --> boolean))
;
(define (exploded-qualified-symbol=? px sx py sy)
  (and (string=? px py) (string=? sx sy)) )

(: exploded-qualified-symbol<? (string string string string --> boolean))
;
(define (exploded-qualified-symbol<? px sx py sy)
  (or
    (and (string=? px py) (string<? sx sy))
    (string<? px py)) )

;;;

;;

(: keyword->symbol (keyword --> symbol))
;
(define (keyword->symbol kwd)
  (string->symbol (keyword->string kwd)) )

(: keyword->uninterned-symbol (keyword --> symbol))
;
(define (keyword->uninterned-symbol kwd)
  (string->uninterned-symbol (keyword->string kwd)) )

;;

;symbol->string drops namespace qualification!
;which means a keyword and a symbol of the same name have the same printname.

(: symbol->keyword ((or keyword symbol) --> keyword))
;
(define (symbol->keyword sym)
  (cond
    ((keyword? sym) (the keyword sym))
    (else           (string->keyword (symbol->string sym)) ) ) )

;;

(: *symbol-printname-details ((or keyword symbol) --> string string))
;
(define (*symbol-printname-details sym)
  (cond
    ((keyword? sym) (values (keyword->string sym) ":"))
    (else           (values (symbol->string sym) ""))) )

(: symbol-printname-details ((or keyword symbol) --> string string))
;
(define (symbol-printname-details sym)
  (let-values (
    ((s p) (*symbol-printname-details sym)))
    ;do not expose the symbol's "raw" printname
    (values (string-copy s) p) ) )

;FIXME (forall (a ...) (a a --> boolean))

(: symbol-printname=? ((or keyword symbol) (or keyword symbol) --> boolean))
;
(define (symbol-printname=? x y)
  (let-values (
    ((sx px) (*symbol-printname-details x))
    ((sy py) (*symbol-printname-details y)) )
    (exploded-qualified-symbol=? px sx py sy) ) )

(: symbol-printname<? ((or keyword symbol) (or keyword symbol) --> boolean))
;
(define (symbol-printname<? x y)
  (let-values (
    ((sx px) (*symbol-printname-details x))
    ((sy py) (*symbol-printname-details y)) )
    (exploded-qualified-symbol<? px sx py sy) ) )

;;

(: symbol-printname-length ((or keyword symbol) --> fixnum))
;
(define (symbol-printname-length sym)
  (cond
    ((keyword? sym)
      ;compensate for leading '###' when only a ':' is printed
      (- (string-length (keyword->string sym)) 2) )
    (else
      (string-length (symbol->string sym)) ) ) )

(: max-symbol-printname-length ((list-of symbol) --> fixnum))
;
(define (max-symbol-printname-length syms)
  (if (null? (check-list 'max-symbol-printname-length syms))
    '()
    (apply max 0 (map symbol-printname-length syms)) ) )

) ;module symbol-name-utils